на bugboard.v8.1c.ru я эту тему не нашел.

Фрагмент:

        // выбираем путь к файлу на диске
        ВыборФайла = Новый ДиалогВыбораФайла(РежимДиалогаВыбораФайла.Сохранение);
        ВыборФайла.МножественныйВыбор = Ложь;
        ВыборФайла.ПолноеИмяФайла = ИмяСРасширением;
        Фильтр = СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(
            НСтр("ru = 'Все файлы (*.%1)|*.%1'"), Расширение, Расширение);
        ВыборФайла.Фильтр = Фильтр;
        ВыборФайла.Каталог = ПутьВыбора;
        
        Если ВыборФайла.Выбрать() Тогда
            
            АдресФайла = ДанныеФайла.НавигационнаяСсылкаТекущейВерсии;
            
            Если ДанныеФайла.ТекущаяВерсия <> ДанныеФайла.Версия Тогда
                АдресФайла = РаботаСФайламиСлужебныйВызовСервера.ПолучитьНавигационнуюСсылкуДляОткрытия(
                    ДанныеФайла.Версия, УникальныйИдентификатор);
            КонецЕсли;	
            
            ИмяФайла = ОбщегоНазначенияКлиентСервер.ПолучитьИмяСРасширением(
                ДанныеФайла.ПолноеНаименованиеВерсии, ДанныеФайла.Расширение);
            
            РазмерВМб = ДанныеФайла.Размер / (1024 * 1024);
            
            ТекстПояснения =
            СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(
                НСтр("ru = 'Выполняется сохранение файла ""%1"" (%2 Мб)...
                           |Пожалуйста, подождите.'"),
                ИмяФайла, 
                ФайловыеФункцииСлужебныйКлиентСервер.ПолучитьСтрокуСРазмеромФайла(РазмерВМб));
                
            Состояние(ТекстПояснения);	
            
            Файл = Новый Файл(ВыборФайла.ПолноеИмяФайла);
            Если Файл.Существует() Тогда
                Если ПутьКФайлуВКеше <> ВыборФайла.ПолноеИмяФайла Тогда
                    Файл.УстановитьТолькоЧтение(Ложь);
                    УдалитьФайлы(ВыборФайла.ПолноеИмяФайла);
                КонецЕсли;
            КонецЕсли;
            
            Если ПутьКФайлуВКеше = "" Тогда
                
                ПередаваемыеФайлы = Новый Массив;
                Описание = Новый ОписаниеПередаваемогоФайла(ВыборФайла.ПолноеИмяФайла, АдресФайла);
                ПередаваемыеФайлы.Добавить(Описание);
                
                ПутьКФайлу = Файл.Путь;
                ПутьКФайлу = ОбщегоНазначенияКлиентСервер.ДобавитьКонечныйРазделительПути(ПутьКФайлу, ОбщегоНазначенияКлиентПовтИсп.ТипПлатформыКлиента());
                
                // Сохраним Файл из БД на диск
                Если ПолучитьФайлы(ПередаваемыеФайлы,, ПутьКФайлу, Ложь) Тогда
                    
                    // для варианта с хранением файлов на диске (на сервере) удаляем Файл из временного хранилища после получения
                    Если ЭтоАдресВременногоХранилища(АдресФайла) Тогда
                        УдалитьИзВременногоХранилища(АдресФайла);
                    КонецЕсли;
                    
                    Если СохранятьСРасшифровкой Тогда
                        ИмяФайлаСПутем = ВыборФайла.ПолноеИмяФайла;
                        
                        Попытка
                            МенеджерКриптографии = ЭлектроннаяЦифроваяПодписьКлиент.ПолучитьМенеджерКриптографии();
                            МенеджерКриптографии.ПарольДоступаКЗакрытомуКлючу = Пароль;
                            
                            ИмяФайлаСПутемРасшифрованное = ИмяФайлаСПутем + ".dec";
                            МенеджерКриптографии.Расшифровать(ИмяФайлаСПутем, ИмяФайлаСПутемРасшифрованное);
                            
                            УдалитьФайлы(ИмяФайлаСПутем);
                            ПереместитьФайл(ИмяФайлаСПутемРасшифрованное, ИмяФайлаСПутем);
                        Исключение
                            УдалитьФайлы(ИмяФайлаСПутем);
                            ВызватьИсключение;
                        КонецПопытки;
                    КонецЕсли;
                    
                    
                    НовыйФайл = Новый Файл(ВыборФайла.ПолноеИмяФайла);
                    
                    НовыйФайл.УстановитьУниверсальноеВремяИзменения(
                        ДанныеФайла.ДатаМодификацииУниверсальная);
                    
                    Состояние(НСтр("ru = 'Файл успешно сохранен'"), , ВыборФайла.ПолноеИмяФайла);
                КонецЕсли;
            Иначе
                Если ПутьКФайлуВКеше <> ВыборФайла.ПолноеИмяФайла Тогда
                    КопироватьФайл(ПутьКФайлуВКеше, ВыборФайла.ПолноеИмяФайла);
                КонецЕсли;
                Состояние(НСтр("ru = 'Файл успешно сохранен'"), , ВыборФайла.ПолноеИмяФайла);
            КонецЕсли;

+(9) Забыла: а до этого в ОткрытьФормуМодально("Отчет", СписокПараметров, КаталогИБ() + "\Dopolnitelno\ЖурналКассира-Операциониста.ert") вместо КаталогИБ() + "\Dopolnitelno\ЖурналКассира-Операциониста.ert" был прописан сетевой путь (имя компа и т. д.)

(13) Говорю же - смотри, что возвращает Каталог. И с каким доступом.

Поправьте меня, если я ошибаюсь. Не похоже на права доступа к папке. Любой веб-клиент запущен на моей машине от моего имени. В первом случае - Internet Explorer записывает файл в указанную мной папку, во втором случае - Mozilla FireFox не хочет это делать.

(8) а где у тебя учитывается ВыборФайла.Каталог после выбора файла?

В общем, скачал Mozilla FireFox 14.0.1 Portable. Подключился к базе, выбрал куда сохранять файл, оно послушно всё отработало.